The goal of this project is to experiment with ways that the University of Victoria (UVic) Libraries can utilize Wikidata to promote interest in the holdings at Special Collections and University Archives (SCUA). The following visualizations use SPARQL queries and the Wikidata Query Service to compile information about people and institutions that have fonds, collections, and correspondence held at UVIC SCUA. As more instances of the “archives at” (P485) property are used to connect SCUA with people and institutions with pages on Wikidata, the visualizations will become more representative of the Archives’ holdings.

Note: The creation of this page was inspired by a similar Wikidata visualization page from the University of Ottawa’s Canadian Archive of Women in STEM project.

Visualizing the Archives’ Holdings through Wikidata Queries

Who has holdings in the Archives?

This table includes both people and organizations that have archival fonds, collections, or correspondence held at UVic SCUA. Note that the list is not exhaustive, and only includes the records creators that have been linked to UVic through the “archives at” (P485) property on Wikidata.

SPARQL query used to generate the table:

SELECT ?Creator ?CreatorLabel
WHERE
{
  ?Creator wdt:P485 wd:Q47518588.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}

 ORDER BY (?CreatorLabel)

Where are these records creators from?

Click the red dots on the map to see the names of records creators who have holdings at UVic SCUA, and to see where they are from. Note that some creators show up multiple times on the map, as they have lived in many locations.

SPARQL query used to generate the map:

#defaultView:Map
SELECT ?Creator ?CreatorLabel ?CorrespondenceAtLabel ?DateofBirthLabel ?ResidenceLabel ?LocationLabel ?CountryOfCitizenship ?Country ?Coordinates 
WHERE
{
  ?Creator wdt:P485 wd:Q47518588.
  
  OPTIONAL {?Creator wdt:P569 ?DateofBirth. }
  
  OPTIONAL {?Creator wdt:P27 ?CountryOfCitizenship. }
  
  OPTIONAL {?Creator wdt:P551 ?Residence.
            ?Residence wdt:P625 ?Coordinates.}
  
  OPTIONAL {?Creator wdt:P131 ?Location.
            ?Location wdt:P625 ?Coordinates.}
  
  OPTIONAL {?Creator wdt:P17 ?Country.
            ?Country wdt:625 ?Coordinates.}
  
  OPTIONAL {?Creator wdt:P485 wd:Q47518588;
           p:P485 [ ps:P485 ?CorrespondenceAt; pq:P518 wd:Q1277575 ].
  } 
      
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}

ORDER BY (?DateofBirth)

*Using the Wikidata Query Service, the results of this query can also be viewed as a table.

When and where were these records creators born?

SPARQL query used to generate the timeline:

#defaultView:Timeline
SELECT ?Creator ?CreatorLabel ?DateOfBirth ?BirthPlace ?BirthPlaceLabel ?Coordinates
{
  ?Creator wdt:P485 wd:Q47518588;
           wdt:P569 ?DateOfBirth.
  
  OPTIONAL {?Creator wdt:P19 ?BirthPlace.
            ?BirthPlace wdt:P625 ?Coordinates.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}
ORDER BY (?DateOfBirth)

*Using the Wikidata Query Service, the results of this query can also be viewed as a table, a map, or a graph.

What occupations do these records creators have?

SPARQL query used to generate the bubble chart:

#defaultView:BubbleChart
SELECT DISTINCT ?OccupationLabel (COUNT (?Creator) as ?Count)
WHERE
{
  ?Creator wdt:P485 wd:Q47518588.
  ?Creator wdt:P106 ?Occupation.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?OccupationLabel
ORDER BY DESC (?Count)

*Using the Wikidata Query Service, the results of this query can also be viewed as a table.

Which records creators have which occupations?

SPARQL query used to generate the table:

SELECT ?OccupationLabel ?CreatorLabel ?Creator ?DateOfBirth 
{
  ?Creator wdt:P485 wd:Q47518588;
           wdt:P569 ?DateOfBirth.
  
  OPTIONAL {?Creator wdt:P106 ?Occupation.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}
ORDER BY (?OccupationLabel)

*Using the Wikidata Query Service, the results of this query can also be viewed as a tree map, and a timeline.

What are the languages spoken by the records creators?

SPARQL query used to generate the bubble chart:

#defaultView:BubbleChart 
SELECT DISTINCT ?LanguageLabel (COUNT (?Creator) as ?Count)
WHERE
{
  ?Creator wdt:P485 wd:Q47518588.
  ?Creator wdt:P1412 ?Language.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?LanguageLabel
ORDER BY DESC (?Count)

*Using the Wikidata Query Service, the results of this query can also be viewed as a table.

Which records creators speak which languages?

SPARQL query used to generate the table:

SELECT ?LanguageLabel ?CreatorLabel ?Creator ?DateOfBirth 
{
  ?Creator wdt:P485 wd:Q47518588;
           wdt:P569 ?DateOfBirth.
  
  OPTIONAL {?Creator wdt:P1412 ?Language.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}
ORDER BY (?LanguageLabel)

*Using the Wikidata Query Service, the results of this query can also be viewed as a tree map, and a timeline.

Experiment: Using Wikidata to highlight correspondence held in archival fonds

As part of this Wikidata project, I experimented with ways to highlight the relationships between creators who have fonds at UVic and their correspondents. Using the Else Lübcke Seel fonds as a case study, I identified all individuals who have correspondence held in Seel’s fonds. I added the “archives at” (P485) property to each of Seel’s correspondents’ Wikidata pages, qualified by “applies to part, aspect, or form” (P518) → “correspondence” (Q1277575). I further qualified the “archives at” statement by listing Else Seel (Q94514551) as the “collection creator” (P6241). For an example, see the “archives at” statement section on Ezra Pound’s Wikidata page.

The following visualizaton results from this experimentation, highlighting that Else Seel corresponded with a variety of people, and that the resulting letters (addressed to Seel) are held together in Seel’s fonds at UVic.

SPARQL query used to generate the dimensions:

#defaultView:Dimensions
SELECT ?AddresseeLabel ?CorrespondentLabel ?CorrespondenceAtLabel 
WHERE
{
  ?Correspondent wdt:P3342 wd:Q94514551;
           wdt:P485 wd:Q47518588;
           p:P485 [ ps:P485 ?CorrespondenceAt; pq:P518 wd:Q1277575 ].
  VALUES ?Addressee { wd:Q94514551 }.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]".}
}

*Using the Wikidata Query Service, the results of this query can also be viewed as a table.